Memasang Rumus Perkiraan Jurnal Umum (21)

Logika verbal dalam kolom ini adalah :

“ Jika kolom Ref berisi Nomor Akun (sebagai argumen kunci) dari Tabel Array (argumen range) Kode_Akun kolom ke-1 (argumen offset), maka tulislah nama akun seperti pada Tabel Array kolom ke-4 (argumen offset). Dan jika kolom Ref berisi Nomor Akun dan kolom Debet bernilai numeric lebih dari 0 (nol), maka tulislah nama akun seperti pada Tabel Array kolom ke-4 (argumen offset). Atau jika kolom Ref berisi Nomor Akun dan kolom Kredit bernilai numeric lebih dari 0 (nol), maka tulislah nama akun seperti pada Tabel Array kolom ke-4 (argumen offset), dan menjorok/merenggang 7 spasi dari garis tulisan kiri. Atau jika kolom Ref tidak berisi/kosong (“ “), maka kolom Perkiraan ini juga kosong (“ “)”.

Marilah kita potong-potong logika verbal ini agar mudah kita pahami, sehingga tidak mengalami kesulitan dalam memasang rumusnya.

1.   “ Jika kolom Ref berisi Nomor Akun (sebagai argumen kunci) dari Tabel Array (argumen range) Kode_Akun kolom ke-1 (argumen offset), maka tulislah nama akun seperti pada Tabel Array kolom ke-4 (argumen offset). Atau jika kolom Ref tidak berisi/kosong (“ “), maka kolom Perkiraan ini juga kosong (“ “)”.

Fungsi-fungsi yang digunakan dalam menuliskan rumus logika ini adalah sebagai berikut :

=IF(F8<>"";VLOOKUP((F8);(Kode_Akun);4);"")

Setelah itu kita coba mengisi sel ‘F8 (dalam kolom Ref) dengan menuliskan salah satu nomor akun yang ada dalam Tabel Array, misalnya ‘511. Maka dalam sel ‘D8 (Kolom Perkiraan) muncul tulisan ‘Beban Sewa. Nomor Akun ‘511, merupakan  argumen  kunci  dari agumen range/Tabel Array kolom ke-1. Sedang ‘Beban Sewa merupakan argumen kunci dari agumen range/Tabel Array kolom ke-4. Dan apabila sel ‘F8 kolom Ref tidak diisi maka pada kolom ‘D8, juga kosong!.

Pemasangan rumus ini dapat dilakukan dengan menuliskan secara langsung ataupun dengan fungsi Wizard yang terdapat dalam MS Excel, sebagai berikut :

Gambar : 2.33

1)    Letakkan krusor pada sel dimana akan ditempatkan suatu hasil (bisa numeric atau text). Arah pointer pada Farmula Bar, klik Edi formula (tanda ‘=’), klik listbox pilih (dengan menyorot) dan kilk fungsi IF. Maka akan muncul kotak dialog yang harus diisi dengan argumen (atau argumen-argumen), yaitu Logical_test, Value_if_true, dan Value_if_false.

Gambar : 2.34

2)    Secara otomatis krusor (berkedip-kedip) berada dalam kolom isian Logical_test. Pointer yang berada pada sheet aktip diarahkan pada sel yang dijadikan argumen ke-1 yang akan diuji, misalnya, F12. Maka dalam kolom isian Logical_test akan tertulis F12, sedang pada sheet aktip, dimana suatu hasil akan ditempatkan tertulis = F12(). Selanjutnya ketiklah logika dari argumen yang dikehendaki yaitu <>”” yang berarti sel tidak kosong/berisi.

3)    Pindahkan pointers pada kolom isian Value_if_true, ketikkan ( ->kurung buka, arahkan pointers pada listbox pilihan fungsi, klik Vlookup sehingga muncul kotak dialog untuk menguji argumen dalam fungsi Vlookup yaitu : Lookup_value, Tabel_array, Col_index_num dan Range_lookup.

Mengisi/memasang argumen dalam fungsi Vlookup :

¨        Pada kolom isian Lookup_value diisi argumen kunci yang akan dituliskan  dalam kolom F12. Dengan cara ketikkan ( ->kurung buka, arahkan pointer pada sel F12, ketik ) ->kurung tutup, (F12).

¨        Pindahkan krusor pada kolom isian Tabel_array, ketikkan ( ->kurung buka, klik Insert pada Menu Bar, sorot Name, klik Paste…, sehingga mucul kotak pilihan (option box), blok Kode_Akun, klik OK ketik ) ->kurung tutup.

¨        Pindahkan krusor pada kolom isian Col_index_num ketik 4 sebagai argumen ofset. Nama rekening berada pada kolom ke-4 dari kiri dalam Tabel array Kode_Akun.

Gambar : 2.35

Gambar : 2.36

4)    Setelah itu pindahkan pointer pada Formula Bar, klik sebelah paling kanan ) ->kurung buka, ketik ) ->kurung tutup, maka akan muncul kembali kotak dialog untuk fungsi IF.

5)    Klik krusor pada kolom isian Value_if_false, ketikkan "" (tanda petik buka dua kali). Yang berarti bahwa apabila argumen yang disyaratkan tidak ada, maka sel ini juga akan tidak ada / kosong.

6)    Kemudian klik OK.

Gambar : 2.37

Gambar : 2.38

Gambar : 2.39

 

2.   “Jika kolom Ref berisi Nomor Akun dan kolom Debet bernilai numeric lebih dari 0 (nol), maka tulislah nama akun seperti pada Tabel Array kolom ke-4 (argumen offset)”.

Fungsi-fungsi yang digunakan dalam menuliskan rumus logika ini adalah:

=IF(AND(F9<>"";G9>0);VLOOKUP((F9);(Kode_Akun);4);"")

Apabila  sel ‘F9 (dalam kolom Ref) ‘berisi’ dengan menuliskan salah satu nomor akun yang ada dalam Tabel Array, misalnya ‘511, dan sel G9>0. Maka dalam sel ‘D9 (Kolom Perkiraan) muncul tulisan ‘Beban Sewa. Dua argumen ini (F9=511 dan G9>0) merupakan syarat yang harus dipenuhi untuk memunculkan nama perkiraan ‘Beban Sewa (agumen range/Tabel Array kolom ke-4). Dan jika sel ‘F9 kolom Ref tidak diisi/kosong maka pada kolom ‘D9, juga kosong!.

Gambar : 2.40

Gambar : 2.41

3.   “(Atau) jika kolom Ref berisi Nomor Akun dan kolom Kredit bernilai numeric lebih dari 0 (nol), maka tulislah nama akun seperti pada Tabel Array kolom ke-4 (argumen offset), dan menjorok/merenggang 7 spasi dari garis tulisan kiri. Atau jika kolom Ref tidak berisi/kosong (“ “), maka kolom Perkiraan ini juga kosong (“ “)”.

Fungsi-fungsi yang digunakan dalam menuliskan rumus logika ini adalah:

=IF(AND(F10<>"";H10>0);CONCATENATE("       ";VLOOKUP((F10);Kode_Akun;4));"")

Gambar : 2.42

7 (tujuh) spasi sebagai tex pertama (argumen ke-1) yang akan digabung dengan tex kedua (argumen ke-2) dari fungsi “CONCATENATE ( )”, dapat diganti denga fungsi pengulangan atau REPT ( ), sebagai berikut :

   =IF(AND(F11<>"";H11>0);CONCATENATE(REPT(" ";7);VLOOKUP((F11); (Kode_Akun);4));"")

Isi sel F11 (dalam kolom Ref) dan nilai numeric H11>0 (kolom Kredit) sebagai syarat penulisan Nama Perkiraan pada sel dimana krusor berada (D11), yang ditulis merenggang 7 spasi dari garis tepi kiri sel. Dan apabila salah satu syarat atau keduanya tidak dipenuhi, maka sel dimana krusor berada kosong/tidak berisi karakter apapun.

Gambar : 2.43

Kemudian disatukan kembali potongan-potongan rumus tadi menjadi :

=IF(OR(AND(F16<>"";G16=0;H16=0);AND(F16<>"";G16>0));VLOOKUP((F16);(Kode_Akun);4);IF(AND(F16<>"";G16=0;H16>0);CONCATENATE(REPT(" ";7);VLOOKUP((F16);(Kode_Akun);4));""))

Salin/copy rumus dari sel D16 ini keseluruh sel dalam kolom Perkiraan.

Gambar : 2.44